# IRAF cshell login file.  [SITE DEPENDENT]

umask	022
source ~iraf/.cshrc

setenv	DISPLAY :0.0
setenv	OPENWINHOME /usr/openwin
setenv	MANPATH	"$OPENWINHOME/man:/usr/lang/man:/usr/share/man:"
setenv	uparm $home/uparm/

set	history	= 100
set	time	= 30
set	mail	= (/usr/spool/mail/$user)
set	notify

setenv	iraf	/iraf/iraf/
if (! -d $iraf) then
    setenv iraf	`(cd ..;pwd)`/
endif
source	$iraf/unix/hlib/irafuser.csh

if ($OSVERSION == 5) then
    setenv LD_LIBRARY_PATH /opt/SUNWspro/lib:$OPENWINHOME/lib
    setenv LM_LICENSE_FILE /opt/SUNWspro/SunTech_License/license.dat
    set prompt = "$user@`uname -n | sed 's+\..*++'`% "
else
    set prompt = "`whoami`@`hostname | sed 's+\..*++'`% "
endif

set cdpath =\
    ($iraf $iraf/noao $iraf/pkg $iraf/sys $iraf/unix $iraf/unix/boot\
     $iraf/local $iraf/noao/imred $iraf/noao/twodspec ~)

alias	cls	'clear;ls'
alias	clu	'clear;users'
alias	clw	'clear;w'
alias	his	'history | tail -15'
alias	pg	'less -Cqm'
alias	sp	'clear;tail -f spool'
alias	win	'/usr/openwin/bin/openwin -noauth'
alias	setarch	'setenv IRAFARCH \!*'

# Set the desired architecture.  This is necessary only for software
# development or maintenance.

switch ($OSVERSION)
case 5:
    setarch ssun
    breaksw
case i386:
    setarch i386
    breaksw
case 4:
    /usr/kvm/sparc
    if (! $status) then
	setarch sparc
    else if (-e $iraf/bin.f68881/cl.e) then
	setarch f68881
    else if (-e $iraf/bin.ffpa/cl.e) then
	setarch ffpa
    endif
    breaksw
endsw
